Lacking Cue Sheet & File Naming

Discuss Max, an open source CD audio extractor and audio converter.
Post Reply
TOKIO
Posts: 12
Joined: Fri Feb 03, 2006 4:20 pm

Lacking Cue Sheet & File Naming

Post by TOKIO » Fri Nov 16, 2007 1:05 pm

I am attempting to use Max 0.7.1 under Leopard; from today with 10.5.1. I have the same problem as others with lack of access to format conversion until a solution for Leopard is found.

I am a "high-end audio" user that want the highest quality rip possible, and will only use lossless formats. I have set up cdparanoia (Full Paranoia) with error correction enabled. (Also check for C2 errors and "Never Allow Skipping".)

I have also checked "Generate a cue sheet". When I put in a CD in my iMac 24" 2.33GHz it is recognized properly by Max 0.7.1 with artist, album name, and song titles etc.

Output files are set to "Music" folder and "Temporary Files" to a folder I named "MaxRips". My problem is that the file names come out as (for example "Max-00d98320-1jOf3EuK.caf" and not their actual names. Also no separate cue sheet is to be found anywhere despite that I checked the cue sheet box.)

What am I doing wrong?

Is this a problem of Leopard compatibility, or am I just doing something wrong?

I would like to rip at the highest possible quality, convert format to a universal lossless format like FLAC (and possibly also to a format readable by iTunes). Occasionally I also need to convert to MP3 using the LAME engine.

Would be grateful for any advice :-)

User avatar
sbooth
Site Admin
Posts: 2450
Joined: Fri Dec 23, 2005 7:45 am
Location: USA
Contact:

Re: Lacking Cue Sheet & File Naming

Post by sbooth » Fri Nov 16, 2007 6:07 pm

If you are running Leopard please use the unstable version posted on the Max website- 0.7.1 is not Leopard compatible so I'm not sure if your problems are Leopard-related or Max-related.

TOKIO
Posts: 12
Joined: Fri Feb 03, 2006 4:20 pm

Re: Lacking Cue Sheet & File Naming

Post by TOKIO » Sat Nov 17, 2007 3:16 pm

Thanks Stephen. Everything works fine now with Max-r1306.tar.bz2.tar

Cheers!

saverio
Posts: 7
Joined: Mon Mar 17, 2008 7:15 pm

Re: Lacking Cue Sheet & File Naming

Post by saverio » Mon Mar 17, 2008 8:54 pm

Hello everyone. I have the same problem, no matter how I configure (with/without cue sheet, rip to a single file, join file on conversion) there is no trace of the cue sheet.

I'm using r1348 on intel iMac, 10.5.2.

This is the log for a ripping session where the CUE file is nowhere to be found:

Code: Select all

2008-03-17 21:47:46 +0100	Rip started for Multiple Tracks
2008-03-17 21:50:59 +0100	Rip completed for Multiple Tracks
2008-03-17 21:50:59 +0100	Encode started for Multiple Tracks [FLAC]
2008-03-17 21:52:58 +0100	Encode completed for Multiple Tracks [FLAC]

User avatar
sbooth
Site Admin
Posts: 2450
Joined: Fri Dec 23, 2005 7:45 am
Location: USA
Contact:

Re: Lacking Cue Sheet & File Naming

Post by sbooth » Tue Mar 18, 2008 12:05 am

If you are ripping to FLAC the cue sheet is contained inside the FLAC file.

saverio
Posts: 7
Joined: Mon Mar 17, 2008 7:15 pm

Re: Lacking Cue Sheet & File Naming

Post by saverio » Tue Mar 18, 2008 7:05 am

yes, but without track titles. As you already pointed out in another thread, embedded cue sheet does not support any other thing than track number and duration, and something "nonstandard" like cuesheet comment à la fb2k is not to be expected (I agree on that). So the problem is that the FLAC loses all the metadata and the program don't retrieve it again from .cdinfo or MusicBrainz. All and all, I think I should just rip to separate files...

User avatar
sbooth
Site Admin
Posts: 2450
Joined: Fri Dec 23, 2005 7:45 am
Location: USA
Contact:

Re: Lacking Cue Sheet & File Naming

Post by sbooth » Tue Mar 18, 2008 2:26 pm

The newest versions of Max will grab the metadata from the .cdinfo file if you open a cue sheet that was created with Max.

As for using them in other programs, you are correct, right now the metadata is basically lost.

theirongiant
Posts: 3
Joined: Thu Apr 05, 2007 4:52 pm
Contact:

Re: Lacking Cue Sheet & File Naming

Post by theirongiant » Tue Mar 18, 2008 6:27 pm

I have 0.8b running on Leopard. Currently I am ripping a disc to two separate file formats: MP3, and FLAC. It is generating a CUE sheet for every single file, instead of creating one large cue file at the end. Each CUE sheet references only the MP3, and only one track at a time.

They look like this:

Code: Select all

REM File created by Max 0.8b
TITLE "FOCAL Le Grand Spectacle Du Son (disc 4)"
PERFORMER "Various"
FILE "03 - Romeo Mochado.mp3" MP3
  TRACK 03 AUDIO
    ISRC FQUA19780110
    TITLE "Romeo Mochado"
    PERFORMER "Bernard Lavilliers"
    INDEX 01 00:00:00

saverio
Posts: 7
Joined: Mon Mar 17, 2008 7:15 pm

Re: Lacking Cue Sheet & File Naming

Post by saverio » Tue Mar 18, 2008 6:45 pm

sbooth wrote:The newest versions of Max will grab the metadata from the .cdinfo file if you open a cue sheet that was created with Max.
If I open the FLAC with embedded cuesheet the cd info is not retrieved.

maxlover
Posts: 36
Joined: Sat Apr 07, 2007 6:37 am
Location: Belgium

Re: Lacking Cue Sheet & File Naming

Post by maxlover » Thu Mar 20, 2008 5:10 pm

It is indeed regrettable that, when putting a cue sheet inside a FLAC file, Max does not ALSO write a regular, detached cue file in the same directory as that FLAC file. It is not as if this would be awfully expensive, or as if new code would have to be written, since Max does write such a cue file when producing anything that is not FLAC... Then, if one does not wan the cue file, well, the Mac user interface has a nice bin.

Retrieving the cdinfo does indeed work, but not always. As discussed here http://sbooth.org/forums/viewtopic.php?f=4&t=1891, I have had about 80% success, but I have no idea of the reason why it does not work for some files.

If yo want to get the metadata out of the cdinfo 'jail', this can be done using Applescript. I did write an Applescript that, when a cdinfo is open in Max, writes a cue file from it. The cue file produced is coded in Mac OS Roman.

bichenoubi
Posts: 29
Joined: Fri Oct 12, 2007 2:13 am

Re: Lacking Cue Sheet & File Naming

Post by bichenoubi » Fri Mar 21, 2008 7:00 pm

maxlover wrote:It is indeed regrettable that, when putting a cue sheet inside a FLAC file, Max does not ALSO write a regular, detached cue file in the same directory as that FLAC file. It is not as if this would be awfully expensive, or as if new code would have to be written, since Max does write such a cue file when producing anything that is not FLAC... Then, if one does not wan the cue file, well, the Mac user interface has a nice bin.

Retrieving the cdinfo does indeed work, but not always. As discussed here http://sbooth.org/forums/viewtopic.php?f=4&t=1891, I have had about 80% success, but I have no idea of the reason why it does not work for some files.

If yo want to get the metadata out of the cdinfo 'jail', this can be done using Applescript. I did write an Applescript that, when a cdinfo is open in Max, writes a cue file from it. The cue file produced is coded in Mac OS Roman.
Would you mind to share your script with us ? I would like to have external cue sheets with meta data. thanks a lot.

maxlover
Posts: 36
Joined: Sat Apr 07, 2007 6:37 am
Location: Belgium

Re: Lacking Cue Sheet & File Naming

Post by maxlover » Sat Mar 22, 2008 3:20 pm

bichenoubi wrote:Would you mind to share your script with us ? I would like to have external cue sheets with meta data. thanks a lot.
No problem. It's a Q&D hack I wrote for myself, so usage is at your own risk.

To install: just as described here: http://sbooth.org/forums/viewtopic.php?f=2&t=1999

To use: when a disk information window is open, select the script in the script menu.

Notes:
- you may want to change the default file names defined in the two first lines.
- the cue file is written in 'Western (Mas OS Roman)'.
- XLD opens those files without problem.

Code: Select all

set audioFileName to " Pistes multiples.flac"
set cueFileName to "Pistes multiples.cue"
set titleString to "TITLE \""
set fileString to "FILE \""
set discIdString to "REM DiscID = \""
set trackString to "  TRACK "
set performerString to "PERFORMER \""
set songwriterString to "SONGWRITER \""
set MCNString to "CATALOG "
set indexString to "    INDEX 01 "
set ISRCString to "    ISRC "
set dateString to "REM DATE "
set genreString to "REM GENRE "
set quoteString to "\""
tell application "Max"
	set MaxFileExists to exists document 1
end tell
if MaxFileExists then
	set cueFile to choose file name with prompt "Cue file ?" default name cueFileName default location the path to desktop
	set cueFileID to open for access cueFile with write permission
	set eof cueFile to 0
	tell application "Max"
		set maxdisk to document 1
		set mc to (count every track of maxdisk)
		set discID to disc ID of maxdisk as string
		set albumTitle to title of maxdisk as string
		set albumArtist to artist of maxdisk as string
		set isCompilation to compilation of maxdisk
		set albumGenre to genre of maxdisk as string
		set albumYear to date of maxdisk as string
		set albumComposer to composer of maxdisk as string
		set discNumber to disc number of maxdisk
		set discTotal to total discs of maxdisk
		set discMCN to MCN of maxdisk as string
	end tell
	writeLine(cueFileID, discIdString, discID, quoteString, "")
	writeLine(cueFileID, titleString, albumTitle, quoteString, "")
	writeLine(cueFileID, performerString, albumArtist, quoteString, "")
	writeLine(cueFileID, songwriterString, albumComposer, quoteString, "")
	writeLine(cueFileID, dateString, albumYear, "", "")
	writeLine(cueFileID, genreString, albumGenre, "", "")
	writeLine(cueFileID, MCNString, discMCN, "", "")
	writeLine(cueFileID, fileString, audioFileName, quoteString, " FLAC")
	repeat with i from 1 to mc
		tell application "Max"
			set maxtrack to track i of maxdisk
			set trackTitle to title of maxtrack as string
			set trackArtist to artist of maxtrack as string
			set trackYear to date of maxtrack as string
			set trackGenre to genre of maxtrack as string
			set trackComposer to composer of maxtrack as string
			set trackNumber to number of maxtrack as string
			set trackISRC to ISRC of maxtrack as string
			set trackFirstSector to first sector of maxtrack
		end tell
		set fframe to trackFirstSector mod 75 as string
		if length of fframe is 1 then
			set fframe to "0" & fframe
		end if
		set fsecond to trackFirstSector div 75 mod 60 as string
		if length of fsecond is 1 then
			set fsecond to "0" & fsecond
		end if
		set fminute to trackFirstSector div 4500 as string
		if length of fminute is 1 then
			set fminute to "0" & fminute
		end if
		if length of trackNumber is 1 then
			set trackNumber to "0" & trackNumber
		end if
		writeLine(cueFileID, trackString, trackNumber, "", " AUDIO")
		writeLine(cueFileID, "    " & titleString, trackTitle, quoteString, "")
		writeLine(cueFileID, "    " & performerString, trackArtist, quoteString, "")
		writeLine(cueFileID, "    " & dateString, trackYear, "", "")
		writeLine(cueFileID, "    " & genreString, trackGenre, "", "")
		writeLine(cueFileID, "    " & songwriterString, trackComposer, quoteString, "")
		writeLine(cueFileID, ISRCString, trackISRC, "", "")
		writeLine(cueFileID, indexString, fminute & ":" & fsecond & ":" & fframe, "", "")
	end repeat
	close access cueFileID
else
	display dialog "There is no open Max document to work with."
end if

on writeLine(cueFileID, labelString, valueString, quoteString, tailString)
	try
		if valueString is not "" then
			if quoteString is not "" then
				if (offset of "\"" in valueString) is not 0 then
					set oldDelimiters to AppleScript's text item delimiters
					set AppleScript's text item delimiters to "\""
					set valueList to every text item of valueString
					set AppleScript's text item delimiters to "''"
					set valueString to valueList as string
					set AppleScript's text item delimiters to oldDelimiters
				end if
			end if
			write labelString & valueString & quoteString & tailString & return to cueFileID
		end if
	on error errorMessage number errorNumber
		close access cueFileID
		error errorMessage number errorNumber
	end try
end writeLine

bdkennedy1
Posts: 5
Joined: Mon Oct 29, 2007 3:55 am

Re: Lacking Cue Sheet & File Naming

Post by bdkennedy1 » Thu Apr 03, 2008 7:41 pm

I have to wonder what good a cue sheet does when it's embedded in the file. Why not in it's own file like every other program?

I'm also wondering why there's no detailed log file created during the ripping process?

agregal
Posts: 6
Joined: Tue Dec 04, 2007 5:14 pm

Re: Lacking Cue Sheet & File Naming

Post by agregal » Fri Oct 24, 2008 2:50 pm

I'm very new to cue sheets and this may seem like a silly question but I need a little help.

Notes:
- you may want to change the default file names defined in the two first lines.
- the cue file is written in 'Western (Mas OS Roman)'.
- XLD opens those files without problem.

1) What should we change the default file names to?

I have also wondered why the cue sheets are imbeded in the file instead of a stand alone cue sheet like other programs such as EAC.

Post Reply